::SpiceGenTcl::Xyce::SemiconductorDevicesTop, Main, Index

method constructor {args} {

    # Creates object of class `Bjt` that describes semiconductor bipolar junction transistor device.
    #  name - name of the device without first-letter designator Q
    #  nc - name of node connected to collector pin
    #  nb - name of node connected to base pin
    #  ne - name of node connected to emitter pin
    #  -model value - name of the model
    #  -area value - scale factor, optional
    #  -m value - multiplier of area and perimeter, optional
    #  -temp value - device temperature, optional
    #  -ic1 value - initial conditions for vbe, optional
    #  -ic2 value - initial conditions for vce, optional
    #  -ns value - name of node connected to substrate pin, optional
    #  -tj value - name of node connected to thermal pin, optional, requires `-ns`
    # ```
    # QXXXXXXX nc nb ne <ns> <tj> mname <area=val> <areac=val>
    # + <areab=val> <m=val> <off> <ic=vbe,vce> <temp=val>
    # + <dtemp=val>
    # ```
    # Example of class initialization:
    # ```
    # Bjt new 1 netc netb nete -model bjtmod -ns nets -area 1e-3
    # ```
    # Synopsis: name nc nb ne -model value ?-ns value ?-tj value?? ?-area value? ?-m value?
    #   ?-temp value? ?-off? ?-ic1 value? ?-ic2 value?
    set arguments [argparse -inline -pfirst -help {Creates object of class 'Bjt' that describes semiconductor bipolar junction transistor device} {
        {-model= -required -help {Name of the model}}
        {-area= -help {Scale factor}}
        {-m= -help {Multiplier of area and perimeter}}
        {-temp= -help {Device temperature}}
        {-off -boolean -help {Initial state}}
        {-ic1= -help {Initial conditions for vbe}}
        {-ic2= -help {Initial conditions for vce}}
        {-ns= -help {Name of node connected to substrate pin}}
        {-tj= -require {ns} -help {Name of node connected to thermal pin}}
        {name -help {Name of the device without first-letter designator}}
        {nc -help {Name of node connected to collector pin}}
        {nb -help {Name of node connected to base pin}}
        {ne -help {Name of node connected to emitter pin}}
    }]
    lappend params [list -posnocheck model [dget $arguments model]]
    if {[dexist $arguments area]} {
        set areaVal [dget $arguments area]
        if {([llength $areaVal]>1) && ([@ $areaVal 0] eq {-eq})} {
            lappend params [list -poseq area [@ $areaVal 1]]
        } else {
            lappend params [list -pos area $areaVal]
        }
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {model area off ns tj name nc nb ne}} {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    set pinList [my FormPinNodeList $arguments {nc nb ne}]
    if {[dexist $arguments ns]} {
        lappend pinList [list ns [dget $arguments ns]]
        if {[dexist $arguments tj]} {
            lappend pinList [list tj [dget $arguments tj]]
        }
    }
    next q[dget $arguments name] $pinList $params
}

method genSPICEString {} {

    # Modify substrate pin string in order to complain square brackets enclosure,
    # see BJT info in reference manual of Xyce
    # Returns: SPICE netlist's string
    set SPICEStr [next]
    if {[dexist [my actOnPin -get -all] ns]} {
        set SPICEList [split $SPICEStr]
        set SPICEStr [join [lreplace $SPICEList 4 4 "\[[@ $SPICEList 4]\]"]]
    }
    return $SPICEStr
}

method constructor {args} {

    # Creates object of class `BjtGPModel` that describes Gummel-Poon model of semiconductor bipolar transistor.
    #  name - name of the model
    #  type - `npn` or `pnp`
    #  args - keyword model parameters, for details please refer to Xyce reference manual, 2.3.17 section.
    # Example of class initialization:
    # ```
    # DiodeModel new bjtmod npn -is 1e-15 -bf 200 -vaf 100 -cje 1e-10
    # ```
    # Synopsis: name type ?-option value ...?
    set paramsNames {level af bf bfm br brm bv c2 c4 ccs cdis cjc cje cjs csub eg esub fc ik ikf ikr  iob irb is isc ise itf jbf jbr jlc jle jrb jtf kf mc me mjc mje mjs ms nc ne nf nk nkf  nle nr pc pe ps psub pt ptf rb rbm rc re tb tcb tempmodel tf tnom tr va vaf var vb vbf  vjc vje vjs vrb vtf xcjc xtb xtf xti}
    next {*}[my ArgsPreprocess $paramsNames {name type} {} {*}[linsert $args 2 -level 1]]
}

method constructor {args} {

    # Creates object of class `Diode` that describes semiconductor diode device.
    #  name - name of the device without first-letter designator D
    #  np - name of node connected to positive pin
    #  nm - name of node connected to negative pin
    #  -model value - name of the model
    #  -area value - area scale factor, optional
    #  -m value - multiplier of area and perimeter, optional
    #  -pj value - perimeter scale factor, optional
    #  -ic value - initial condition, optional
    #  -temp value - device temperature, optional
    #  -custparams list - key that collects all arguments at the end of device definition, to provide an ability
    #  to add custom parameters in form `-custparams param1 param1Val param2 {-eq param2eq} param3 param3Val
    #  ...` Must be specified after all others options. Optional.
    # ```
    # D<name> <(+) node> <(-) node> <model name> [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # Diode new 1 netp netm -model diomod -area 1e-6
    # ```
    # Synopsis: name np nm -model value ?-area value? ?-pj value? ?-ic value? ?-m value? ?-temp value?
    #   ?-custparams param1 \{?-eq|-poseq|-posnocheck|-pos|-nocheck? param1Val\} ...?
    set arguments [argparse -inline -pfirst -help {Creates object of class `Diode` that describes semiconductor diode device} {
        {-model= -required -help {Name of the model}}
        {-area= -help {Area scale factor}}
        {-pj= -help {Perimeter scale factor}}
        {-ic= -help {Initial condition}}
        {-m= -help {Multiplier of area and perimeter}}
        {-temp= -help {Device temperature}}
        {-custparams -catchall -help {Key that collects all arguments at the end of device definition, to provide an ability to add custom parameters in form '-custparams param1 param1Val param2 {-eq param2eq} param3 param3Val ...'}}
        {name -help {Name of the device without first-letter designator}}
        {np -help {Name of node connected to positive pin}}
        {nm -help {Name of node connected to negative pin}}
    }]
    lappend params [list -posnocheck model [dget $arguments model]]
    if {[dexist $arguments area]} {
        set areaVal [dget $arguments area]
        if {([llength $areaVal]>1) && ([@ $areaVal 0] eq {-eq})} {
            lappend params [list -poseq area [@ $areaVal 1]]
        } else {
            lappend params [list -pos area $areaVal]
        }
    }
    if {[dexist $arguments pj]} {
        set pjVal [dget $arguments pj]
        if {([llength $pjVal]>1) && ([@ $pjVal 0] eq {-eq})} {
            lappend params [list -poseq pj [@ $pjVal 1]]
        } else {
            lappend params [list -pos pj $pjVal]
        }
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {model custparams area pj name np nm}} {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    if {[dget $arguments custparams] ne {}} {
        if {[llength [dget $arguments custparams]]%2!=0} {
            return -code error "Custom parameters list must be even length"
        }
        set custParamDict [dcreate {*}[dget $arguments custparams]]
        dict for {paramName value} $custParamDict {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    next d[dget $arguments name] [my FormPinNodeList $arguments {np nm}] $params
}

method constructor {args} {

    # Creates object of class `DiodeModel` that describes semiconductor diode model.
    #  name - name of the model
    #  args - keyword model parameters, for details please refer to Xyce reference manual, 2.3.8 section.
    # Example of class initialization:
    # ```
    # DiodeModel new diodemod -is 1e-14 -n 1.2 -rs 0.01 -cj0 1e-9
    # ```
    # Synopsis: name ?-option value ...?
    set paramsNames {level af bv cj cj0 cjo cjp cjsw eg fc fcs ibv ibvl ikf is isr js jsw kf m mjsw n nbv nbvl nr ns php rs tbv1 tbv2 tikf tnom trs trs1 trs2 tt vb vj vjsw xti}
    next {*}[my ArgsPreprocess $paramsNames {name type} type {*}[linsert $args 1 d]]
}

method constructor {args} {

    # Creates object of class `Jfet` that describes semiconductor junction FET device.
    #  name - name of the device without first-letter designator J
    #  nd - name of node connected to drain pin
    #  ng - name of node connected to gate pin
    #  ns - name of node connected to source pin
    #  -model value - name of the model
    #  -area value - scale factor, optional
    #  -temp value - device temperature, optional
    # ```
    # J<name> <drain node> <gate node> <source node> <model name> [area value] [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # Jfet new 1 netd netg nets -model jfetmod -area {-eq area*2} -temp 25
    # ```
    # Synopsis: name nd ng ns -model value ?-area value? ?-temp value?
    set arguments [argparse -inline -pfirst -help {Creates object of class 'Jfet' that describes semiconductor junction FET device} {
        {-model= -required -help {Name of the model}}
        {-area= -help {Emitter scale factor}}
        {-temp= -help {Device temperature}}
        {name -help {Name of the device without first-letter designator}}
        {nd -help {Name of node connected to drain pin}}
        {ng -help {Name of node connected to gate pin}}
        {ns -help {Name of node connected to source pin}}
    }]
    lappend params [list -posnocheck model [dget $arguments model]]
    if {[dexist $arguments area]} {
        set areaVal [dget $arguments area]
        if {([llength $areaVal]>1) && ([@ $areaVal 0] eq {-eq})} {
            lappend params [list -poseq area [@ $areaVal 1]]
        } else {
            lappend params [list -pos area $areaVal]
        }
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {model area name nd ng ns}} {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    next j[dget $arguments name] [my FormPinNodeList $arguments {nd ng ns}] $params
}

method constructor {args} {

    # Creates object of class `Jfet1Model` that describes JFET level 1 model with Parker Skellern modification.
    #  name - name of the model
    #  type - `njf` or `pjf`
    #  args - keyword model parameters, for details please refer to Xyce reference manual, 2.3.18 section.
    # Example of class initialization:
    # ```
    # Jfet1Model new jfetmod njf -vto 2 -beta 1e-3 -lambda 1e-4 -cgd 1e-12
    # ```
    # Synopsis: name type ?-option value ...?
    set paramsNames {level af b beta cgd cgs delta fc is kf lambda pb rd rs tempmodel theta tnom vto}
    next {*}[my ArgsPreprocess $paramsNames {name type} {} {*}[linsert $args 2 -level 1]]
}

method constructor {args} {

    # Creates object of class `Jfet2Model` that describes JFET level 2 model with Parker Skellern modification.
    #  name - name of the model
    #  type - `njf` or `pjf`
    #  args - keyword model parameters, for details please refer to Xyce reference manual, 2.3.18 section.
    # Example of class initialization:
    # ```
    # Jfet2Model new jfetmod njf -vto -2 -beta 10e-4 -rs 1e-4 -vbi 1.2
    # ```
    # Synopsis: name type ?-option value ...?
    set paramsNames {level af b beta cgd cgs delta fc is kf lambda pb rd rs tempmodel theta tnom vto}
    next {*}[my ArgsPreprocess $paramsNames {name type} {} {*}[linsert $args 2 -level 2]]
}

method constructor {args} {

    # Creates object of class `Mesfet` that describes semiconductor MESFET device.
    #  name - name of the device without first-letter designator Z
    #  nd - name of node connected to drain pin
    #  ng - name of node connected to gate pin
    #  ns - name of node connected to source pin
    #  -model value - name of the model
    #  -area value - scale factor, optional
    #  -temp value - device temperature, optional
    # ```
    # Z<name> < drain node> <gate node> <source node> <model name> [area value] [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # Mesfet new 1 netd netg nets -model mesfetmod -area {-eq area*2}
    # ```
    # Synopsis: name nd ng ns -model value ?-area value? ?-temp value?
    set arguments [argparse -inline -pfirst -help {Creates object of class 'Mesfet' that describes semiconductor MESFET device} {
        {-model= -required -help {Name of the model}}
        {-area= -help {Scale factor}}
        {-temp= -help {Device temperature}}
        {name -help {Name of the device without first-letter designator}}
        {nd -help {Name of node connected to drain pin}}
        {ng -help {Name of node connected to gate pin}}
        {ns -help {Name of node connected to source pin}}
    }]
    lappend params [list -posnocheck model [dget $arguments model]]
    if {[dexist $arguments area]} {
        set areaVal [dget $arguments area]
        if {([llength $areaVal]>1) && ([@ $areaVal 0] eq {-eq})} {
            lappend params [list -poseq area [@ $areaVal 1]]
        } else {
            lappend params [list -pos area $areaVal]
        }
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {model area name nd ng ns}} {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    next z[dget $arguments name] [my FormPinNodeList $arguments {nd ng ns}] $params
}

method constructor {args} {

    # Creates object of class `Mesfet1Model` that describes MESFET model by Statz e.a..
    #  name - name of the model
    #  type - `nmf` or `pmf`
    #  args - keyword model parameters, for details please refer to Xyce reference manual, 2.3.19 section.
    # Example of class initialization:
    # ```
    # Jfet2Model new jfetmod njf -vto -2 -beta 10e-4 -rs 1e-4 -vbi 1.2
    # ```
    # Synopsis: name type ?-option value ...?
    set paramsNames {level af alpha b beta cgd cgs fc is kf lambda pb rd rs tempmodel tnom vto}
    next {*}[my ArgsPreprocess $paramsNames {name type} {} {*}[linsert $args 2 -level 1]]
}

method constructor {args} {

    # Creates object of class `Mosfet` that describes semiconductor MOSFET device.
    #  name - name of the device without first-letter designator M
    #  nd - name of node connected to drain pin
    #  ng - name of node connected to gate pin
    #  ns - name of node connected to source pin
    #  -model value - name of the model
    #  -m value - multiplier, optional
    #  -l value - length of channel, optional
    #  -w value - width of channel, optional
    #  -ad value - diffusion area of drain, optional, forbids `-nrd`
    #  -as value - diffusion area of source, optional, forbids `-nrs`
    #  -pd value - perimeter area of drain, optional
    #  -ps value - perimeter area of source, optional
    #  -nrd value - equivalent number of squares of the drain diffusions
    #  -nrs value - equivalent number of squares of the source diffusions
    #  -temp value - device temperature
    #  -ic value - initial conditions for vds, vgs and vbs, in form of three element list, optional, require 4th
    #    node
    #  -off - initial state, optional
    #  -n4 value - name of 4th node;
    #  -n5 value - name of 5th node, require `-n4`, optional
    #  -n6 value - name of 6th node, require `-n5`, optional
    #  -n7 value - name of 7th node, require `-n6`, optional
    #  -custparams - key that collects all arguments at the end of device definition, to provide an ability to
    #  add custom parameters in form `-custparams param1 param1Val param2 {-eq param2eq} param3 param3Val ...`
    #  Must be specified after all others options. Optional.
    # ```
    # M<name> <drain node> <gate node> <source node>
    # + <bulk/substrate node> <model name>
    # + [L=<value>] [W=<value>]
    # + [AD=<value>] [AS=<value>]
    # + [PD=<value>] [PS=<value>]
    # + [NRD=<value>] [NRS=<value>]
    # + [M=<value] [IC=<value, ...>]
    # ```
    # Example of class initialization:
    # ```
    # Mosfet new 1 netd netg nets -model mosfetmod -l 1e-6 -w 10e-3 -n4 netsub -n5 net5
    # ```
    # Synopsis: name nd ng ns -model value ?-n4 value ?-n5 value ?-n6 value ?-n7 value???? ?-m value?
    #   ?-l value? ?-w value? ?-ad value|-nrd value? ?-as value|-nrs value? ?-temp value? ?-off? ?-pd value?
    #   ?-ps value? ?-ic \{value value value\}?
    #   ?-custparams param1 \{?-eq|-poseq|-posnocheck|-pos|-nocheck? param1Val\} ...?
    set arguments [argparse -inline -pfirst -help {Creates object of class 'Mosfet' that describes semiconductor MOSFET device} {
        {-model= -required -help {Name of the model}}
        {-m= -help Multiplier}
        {-l= -help {Length of channel}}
        {-w= -help {Width of channel}}
        {-ad= -forbid {nrd} -help {Diffusion area of drain}}
        {-as= -forbid {nrs} -help {Diffusion area of source}}
        {-pd= -help {Perimeter area of drain}}
        {-ps= -help {Perimeter area of source}}
        {-nrd= -forbid {ad} -help {Equivalent number of squares of the drain diffusions}}
        {-nrs= -forbid {as} -help {Equivalent number of squares of the source diffusions}}
        {-temp= -help {Device temperature}}
        {-ic= -validate {[llength $arg]==3} -help {Initial conditions for vds, vgs and vbs, in form of three element list}}
        {-n4= -help {Name of 4th node}}
        {-n5= -require {n4} -help {Name of 5th node}}
        {-n6= -require {n5} -help {Name of 6th node}}
        {-n7= -require {n7} -help {Name of 7th node}}
        {-custparams -catchall -help {Key that collects all arguments at the end of device definition, to provide an ability to add custom parameters in form '-custparams param1 param1Val param2 {param2eq -eq} param3 param3Val ...'}}
        {name -help {Name of the device without first-letter designator}}
        {nd -help {Name of node connected to drain pin}}
        {ng -help {Name of node connected to gate pin}}
        {ns -help {Name of node connected to source pin}}
    }]
    lappend params [list -posnocheck model [dget $arguments model]]
    if {[dexist $arguments ic]} {
        lappend params [list -nocheck ic [join [dget $arguments ic] ,]]
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {model off ic n4 n5 n6 n7 custparams name nd ng ns}} {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    if {[dget $arguments custparams] ne {}} {
        if {[llength [dget $arguments custparams]]%2!=0} {
            return -code error "Custom parameters list must be even length"
        }
        set custParamDict [dcreate {*}[dget $arguments custparams]]
        dict for {paramName value} $custParamDict {
            if {[@ $value 0] eq {-eq}} {
                lappend params [list -eq $paramName [@ $value 1]]
            } else {
                lappend params [list $paramName $value]
            }
        }
    }
    set pinList [my FormPinNodeList $arguments {nd ng ns}]
    if {[dexist $arguments n4]} {
        lappend pinList [list n4 [dget $arguments n4]]
        if {[dexist $arguments n5]} {
            lappend pinList [list n5 [dget $arguments n5]]
            if {[dexist $arguments n6]} {
                lappend pinList [list n6 [dget $arguments n6]]
                if {[dexist $arguments n7]} {
                    lappend pinList [list n7 [dget $arguments n7]]
                }
            }
        }
    }
    next m[dget $arguments name] $pinList $params
}