::SpiceGenTcl::Common::BasicDevicesTop, Main, Index

method constructor {name npNode nmNode args} {

    # Creates object of class `Capacitor` that describes capacitor.
    #  name - name of the device without first-letter designator C
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -c - capacitance value
    #  -m - multiplier value, optional
    #  -temp - device temperature, optional, optional
    #  -tc1 - linear thermal coefficient, optional
    #  -tc2 - quadratic thermal coefficient, optional
    #  -ic - initial condition, optional
    # Simple capacitor:
    # ```
    # CXXXXXXX n+ n- <value> <m=val> <temp=val> <tc1=val> <tc2=val>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::BasicDevices::Capacitor new 1 netp netm -c 1e3 -tc1 1 -temp {temp_amb -eq}
    # ```
    set arguments [argparse -inline {
        {-c= -required}
        -m=
        -temp=
        -tc1=
        -tc2=
        -ic=
    }]
    if {([llength $cVal]>1) && ([lindex $cVal 1]=="-eq")} {
        lappend params "c [lindex $cVal 0] -poseq"
    } else {
        lappend params "c $cVal -pos"
    }

    dict for {paramName value} $arguments {
        if {$paramName ni {c}} {
            lappend params "$paramName $value"
        }
    }
    next c$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `CSwitch` that describes current controlled switch device.
    #  name - name of the device without first-letter designator W
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -icntrl - source of control current
    #  -model - model name
    #  -on/-off - initial state of switch
    # ```
    # WYYYYYYY N+ N- VNAM MODEL <ON> <OFF>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ngspice::BasicDevices::CSwitch new 1 net1 0 -icntrl v1 -model sw1 -on
    # ```
    set arguments [argparse -inline {
        {-icntrl= -required}
        {-model= -required}
        {-on -forbid {off}}
        {-off -forbid {on}}
    }]
    lappend params "icntrl [dict get $arguments icntrl] -posnocheck"
    lappend params "model [dict get $arguments model] -posnocheck"
    if {[dict exists $arguments on]} {
        lappend params {on -sw}
    } elseif {[dict exists $arguments off]} {
        lappend params {off -sw}
    }
    next w$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Inductor` that describes inductor.
    #  name - name of the device without first-letter designator L
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -l - inductance value
    #  -m - multiplier value, optional
    #  -temp - device temperature, optional, optional
    #  -tc1 - linear thermal coefficient, optional
    #  -tc2 - quadratic thermal coefficient, optional
    # Simple inductor:
    # ```
    # LXXXXXXX n+ n- <value> <m=val> <temp=val> <tc1=val> <tc2=val>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::BasicDevices::Inductor new 1 netp netm -l 1e3 -tc1 1 -temp {temp_amb -eq}
    # ```
    set arguments [argparse -inline {
        {-l= -required}
        -m=
        -temp=
        -tc1=
        -tc2=
    }]
    set lVal [dict get $arguments l]
    if {([llength $lVal]>1) && ([lindex $lVal 1]=="-eq")} {
        lappend params "l [lindex $lVal 0] -poseq"
    } else {
        lappend params "l $lVal -pos"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {l}} {
            lappend params "$paramName $value"
        }
    }
    next l$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Resistor` that describes resistor.
    #  name - name of the device without first-letter designator R
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -r - resistance value
    #  -m - multiplier value, optional
    #  -temp - device temperature, optional, optional
    #  -tc1 - linear thermal coefficient, optional
    #  -tc2 - quadratic thermal coefficient, optional
    # Simple resistor:
    # ```
    # RXXXXXXX n+ n- <value> <m=val> <temp=val> <tc1=val> <tc2=val>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::BasicDevices::Resistor new 1 netp netm -r 1e3 -tc1 1 -temp {temp_amb -eq}
    # ```
    set arguments [argparse -inline {
        {-r= -required}
        -m=
        -temp=
        -tc1=
        -tc2=
    }]
    set rVal [dict get $arguments r]
    if {([llength $rVal]>1) && ([lindex $rVal 1]=="-eq")} {
        lappend params "r [lindex $rVal 0] -poseq"
    } else {
        lappend params "r $rVal -pos"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {r}} {
            lappend params "$paramName $value"
        }
    }
    next r$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name pins subName params} {

    # Creates object of class `SubcircuitInstance` that describes subcircuit instance.
    #  name - name of the device without first-letter designator X
    #  pins - list of pins {{pinName nodeName} {pinName nodeName} ...}
    #  subName - name of subcircuit definition
    #  params - {{paramName paramValue ?-eq?} {paramName paramValue ?-eq?}}
    # ```
    # XYYYYYYY N1 <N2 N3 ...> SUBNAM
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::BasicDevices::SubcircuitInstance new 1 {{plus net1} {minus net2}} rcnet {{r 1} {c cpar -eq}}
    # ```
    set params [linsert $params 0 "model $subName -posnocheck"]
    next x$name $pins $params
}

method constructor {subcktObj name nodes args} {

    # Creates object of class `SubcircuitInstanceAuto` that describes subcircuit instance with already created subcircuit definition object.
    #  subcktObj - object of subcircuit that defines it's pins, subName and parameters
    #  nodes - list of nodes connected to pins in the same order as pins in subcircuit definition {nodeName1 nodeName2 ...}
    #  args - parameters as argument in form : -paramName {paramValue ?-eq?} -paramName {paramValue ?-eq?}
    # ```
    # XYYYYYYY N1 <N2 N3 ...> SUBNAM
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::BasicDevices::SubcircuitInstanceAuto new $subcktObj 1 {net1 net2} -r 1 -c {cpar -eq}
    # ```

    # check that inputs object class is Subcircuit
    if {[info object class $subcktObj "::SpiceGenTcl::Subcircuit"]!=1} {
        set objClass [info object class $subcktObj]
        error "Wrong object class '$objClass' is passed as subcktObj, should be '::SpiceGenTcl::Subcircuit'"
    }
    # get name of subcircuit
    set subName [$subcktObj configure -Name]
    # get pins names of subcircuit
    set pinsNames [dict keys [$subcktObj getPins]]
    # check if number of pins in subcircuit definition matchs the number of supplied nodes
    if {[llength $pinsNames]!=[llength $nodes]} {
        error "Wrong number of nodes '[llength $nodes]' in definition, should be '[llength $pinsNames]'"
    }
    # create list of pins and connected nodes
    foreach pinName $pinsNames node $nodes {
        lappend pinsList "$pinName $node"
    }
    # get parameters names of subcircuit
    set paramsNames [dict keys [$subcktObj getParams]]
    foreach paramName $paramsNames {
        lappend paramDefList "-${paramName}="
    }
    if {[info exists paramDefList]} {
        # create definition for argparse module for passing parameters as optional arguments
        set arguments [argparse -inline "
            [join $paramDefList \n]
        "]
        # create list of parameters and values from which were supplied by args
        dict for {paramName value} $arguments {
            lappend params "$paramName $value"
        }
    } else {
        set params ""
    }
    set params [linsert $params 0 "model $subName -posnocheck"]
    next x$name $pinsList $params
}

method constructor {name npNode nmNode ncpNode ncmNode args} {

    # Creates object of class `VSwitch` that describes voltage controlled switch device.
    #  name - name of the device without first-letter designator S
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  ncpNode - name of node connected to positive controlling pin
    #  ncmNode - name of node connected to negative controlling pin
    #  -model - model name
    #  -on/-off - initial state of switch
    # ```
    # SXXXXXXX N+ N- NC+ NC- MODEL <ON> <OFF>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ngspice::BasicDevices::VSwitch new 1 net1 0 netc 0 -model sw1 -on
    # ```
    set arguments [argparse -inline {
        {-model= -required}
        {-on -forbid {off}}
        {-off -forbid {on}}
    }]
    lappend params "model [dict get $arguments model] -posnocheck"
    if {[dict exists $arguments on]} {
        lappend params {on -sw}
    } elseif {[dict exists $arguments off]} {
        lappend params {off -sw}
    }
    next s$name [list "np $npNode" "nm $nmNode" "ncp $ncpNode" "ncm $ncmNode"] $params
}