::SpiceGenTcl::Ltspice::SourcesTop, Main, Index

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-dc= -default 0}
        {-ac= -required}
        -rser=
        -cpar=
    }]
    set dcVal [dget $arguments dc]
    if {([llength $dcVal]>1) && ([@ $dcVal 1] eq "-eq")} {
        lappend params "dc [@ $dcVal 0] -poseq"
    } else {
        lappend params "dc $dcVal -pos"
    }
    set acVal [dget $arguments ac]
    if {([llength $acVal]>1) && ([@ $acVal 1] eq "-eq")} {
        lappend params "ac [@ $acVal 0] -eq"
    } else {
        lappend params "ac $acVal"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {dc ac}} {
            if {([llength $value]>1) && ([@ $value 1] eq "-eq")} {
                lappend params "$paramName [@ $value 0] -eq"
            } else {
                lappend params "$paramName $value"
            }
        }
    }
    next $type$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `BehaviouralSource` that describes behavioural source.
    #  name - name of the device without first-letter designator B
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -i - current expression
    #  -v - voltage expression
    #  -ic - initial condition
    #  -tripdv - voltage control step rejection
    #  -tripdt - voltage control time step rejection
    # ```
    # Bnnn n001 n002 V=<expression> [ic=<value>]
    # + [tripdv=<value>] [tripdt=<value>]
    # + [laplace=<expression> [window=<time>]
    # + [nfft=<number>] [mtol=<number>]]
    # ```
    # ```
    #  Bnnn n001 n002 I=<expression> [ic=<value>]
    # + [tripdv=<value>] [tripdt=<value>] [Rpar=<value>]
    # + [laplace=<expression> [window=<time>]
    # + [nfft=<number>] [mtol=<number>]]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::BehaviouralSource new 1 netp netm -v "V(a)+V(b)+pow(V(c),2)"
    # ```
    # Synopsis: name npNode nmNode -v value ?-ic value? ?-tripdv value -tripdt value? ?-laplace value
    #   ?-window value? ?-nfft value? ?-mtol value??
    # Synopsis: name npNode nmNode -i value ?-ic value? ?-tripdv value -tripdt value? ?-laplace value
    #   ?-window value? ?-nfft value? ?-mtol value??
    set arguments [argparse -inline {
        {-i= -forbid v}
        {-v= -forbid i}
        -ic=
        {-tripdv= -require tripdt}
        {-tripdt= -require tripdv}
        -laplace=
        {-window= -require laplace}
        {-nfft= -require laplace}
        {-mtol= -require laplace}
    }]
    if {[dexist $arguments i]} {
        lappend params "i [dget $arguments i] -eq"
    } elseif {[dexist $arguments v]} {
        lappend params "v [dget $arguments v] -eq"
    } else {
        return -code error "Equation must be specified as argument to -i or -v"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {i v}} {
            lappend params "$paramName $value"
        }
    }
    next b$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-dc= -required}
        -rser=
        -cpar=
    }]
    set dcVal [dget $arguments dc]
    if {([llength $dcVal]>1) && ([@ $dcVal 1] eq "-eq")} {
        lappend params "dc [@ $dcVal 0] -poseq"
    } else {
        lappend params "dc $dcVal -pos"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {dc}} {
            if {([llength $value]>1) && ([@ $value 1] eq "-eq")} {
                lappend params "$paramName [@ $value 0] -eq"
            } else {
                lappend params "$paramName $value"
            }
        }
    }
    next $type$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-v1= -forbid i1}
        {-i1= -forbid v1}
        {-v2= -forbid i2}
        {-i2= -forbid v2}
        {-td1= -required}
        {-tau1= -required}
        {-td2= -required}
        {-tau2= -required}
        -rser=
        -cpar=
    }]
    my AliasesKeysCheck $arguments [list v1 i1]
    my AliasesKeysCheck $arguments [list v2 i2]
    set paramsOrder [list v1 i1 v2 i2 td1 tau1 td2 tau2]
    lappend params "model exp -posnocheck"
    my ParamsProcess $paramsOrder $arguments params
    dict for {paramName value} $arguments {
        if {$paramName ni $paramsOrder} {
            if {([llength $value]>1) && ([@ $value 1] eq "-eq")} {
                lappend params "$paramName [@ $value 0] -eq"
            } else {
                lappend params "$paramName $value"
            }
        }
    }
    next $type$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Iac` that describes ac current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -dc - DC current value, default 0
    #  -ac - AC current value
    # ```
    # Ixxx n+ n- <current> AC=<amplitude>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Iac new 1 netp netm -ac 10
    # ```
    # Synopsis: name npNode nmNode -ac value ?-dc value?
    if {"-rser" in $args || "-cpar" in $args} {
        return -code error "Current source doesn't support rser and cpar parameters"
    }
    next $name i $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Idc` that describes simple constant current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -dc - DC current value
    # ```
    # Ixxx n+ n- <current>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Idc new 1 netp netm -dc 10
    # ```
    # Synopsis: name npNode nmNode -dc value
    if {"-rser" in $args || "-cpar" in $args} {
        return -code error "Current source doesn't support rser and cpar parameters"
    }
    next $name i $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Iexp` that describes exponential current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -i1 - initial value
    #  -i2 - pulsed value
    #  -td1 - rise delay time
    #  -tau1 - rise time constant
    #  -td2 - fall delay time
    #  -tau2 - fall time constant
    # ```
    # Ixxx n+ n- EXP(I1 I2 Td1 Tau1 Td2 Tau2)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Iexp new 1 net1 net2 -i1 0 -i2 1 -td1 1e-9 -tau1 1e-9 -td2 {td2 -eq} -tau2 10e-6
    # ```
    # Synopsis: name npNode nmNode -i1 value -i2 value -td1 value -tau1 value -td2 value -tau2 value
    next $name i $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Ipulse` that describes pulse current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -low - low value, aliases: -voff, -ioff
    #  -high - high value, aliases: -von, ion
    #  -td - time delay
    #  -tr - rise time
    #  -tf - fall time
    #  -pw - width of pulse, alias -ton
    #  -per - period time, alias -tper
    #  -np - number of pulses, optional, alias -ncycles
    # ```
    # Ixxx n+ n- PULSE(Ioff Ion Tdelay Trise Tfall Ton Tperiod Ncycles)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Ipulse new 1 net1 net2 -low 0 -high 1 -td {td -eq} -tr 1e-9 -tf 1e-9 -pw 10e-6 -per 20e-6 -np {np -eq}
    # ```
    # Synopsis: name npNode nmNode -low|ioff value -high|ion value -td value -tr value -tf value -pw|ton value
    #   -per|tper value ?-np|ncycles value?
    if {"-rser" in $args || "-cpar" in $args} {
        return -code error "Current source doesn't support rser and cpar parameters"
    }
    next $name i $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Ipwl` that describes piece-wise current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -seq - sequence of pwl points in form {t0 v0 t1 v1 t2 v2 t3 v3 ...}
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Ixxx n+ n- PWL(t1 i1 t2 i2 t3 i3...)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Ipwl new 1 npNode nmNode -seq {0 0 {t1 -eq} 1 2 2 3 3 4 4}
    # ```
    # Synopsis: name npNode nmNode -seq list
    next $name i $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Isffm` that describes single-frequency FM current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -i0 - initial value, aliases: -voff, -v0, -ioff
    #  -ia - pulsed value, aliases: -vamp, -va, -iamp
    #  -fc - carrier frequency, alias -fcar
    #  -mdi - modulation index
    #  -fs - signal frequency, alias -fsig
    # ```
    # Ixxx n+ n- SFFM(Ioff Iamp Fcar MDI Fsig)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Isin new 1 net1 net2 -i0 0 -ia 1 -fc {freq -eq} -mdi 0 -fs 1e3
    # ```
    # Synopsis: name npNode nmNode -i0|ioff value -ia|iamp value -fc|fcar value -mdi value -fs|fsig value
    next $name i $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Isin` that describes sinusoidal current source.
    #  name - name of the device without first-letter designator I
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -v0 - DC shift value, aliases: -voffset, -v0, -ioffset
    #  -va - amplitude value, aliases: -vamp, -va, -iamp
    #  -freq - frequency of sinusoidal signal
    #  -td - time delay, optional
    #  -theta - damping factor, optional, require -td
    #  -phase - phase of signal, optional, require -td and -theta, alias -phi
    #  -ncycles - number of cycles, optional, require -td, -theta and -phase
    # ```
    # Ixxx n+ n- SINE(Ioffset Iamp Freq Td Theta Phi Ncycles)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Isin new 1 net1 net2 -v0 0 -va 2 -freq {freq -eq} -td 1e-6 -theta {theta -eq}
    # ```
    # Synopsis: name npNode nmNode -i0|ioffset value -ia|iamp value -freq value ?-td value ?-theta value
    #   ?-phase|phi value ?-ncycles value????
    if {"-rser" in $args || "-cpar" in $args} {
        return -code error "Current source doesn't support rser and cpar parameters"
    }
    next $name i $npNode $nmNode {*}$args
}

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-low= -forbid {voff ioff}}
        {-voff= -forbid {low ioff}}
        {-ioff= -forbid {low voff}}
        {-high= -forbid {von ion}}
        {-von= -forbid {high ion}}
        {-ion= -forbid {high von}}
        {-td= -required}
        {-tr= -required}
        {-tf= -required}
        {-pw= -forbid ton}
        {-ton= -forbid pw}
        {-per= -forbid tper}
        {-tper= -forbid per}
        {-np= -forbid ncycles}
        {-ncycles= -forbid np}
        -rser=
        -cpar=
    }]
    my AliasesKeysCheck $arguments [list low voff ioff]
    my AliasesKeysCheck $arguments [list high von ion]
    my AliasesKeysCheck $arguments [list pw ton]
    my AliasesKeysCheck $arguments [list per tper]
    set paramsOrder [list low voff ioff high von ion td tr tf pw ton per tper np ncycles]
    lappend params "model pulse -posnocheck"
    my ParamsProcess $paramsOrder $arguments params
    dict for {paramName value} $arguments {
        if {$paramName ni $paramsOrder} {
            if {([llength $value]>1) && ([@ $value 1] eq "-eq")} {
                lappend params "$paramName [@ $value 0] -eq"
            } else {
                lappend params "$paramName $value"
            }
        }
    }
    next $type$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-seq= -required}
        -rser=
        -cpar=
    }]
    set pwlSeqVal [dget $arguments seq]
    set pwlSeqLen [llength $pwlSeqVal]
    if {$pwlSeqLen%2} {
        return -code error "Number of elements '$pwlSeqLen' in pwl sequence is odd in element '$type$name', must be even"
    } elseif {$pwlSeqLen<4} {
        return -code error "Number of elements '$pwlSeqLen' in pwl sequence in element '$type$name' must be >=4"
    }
    # parse pwlSeq argument
    for {set i 0} {$i<[llength $pwlSeqVal]/2} {incr i} {
        set 2i [* 2 $i]
        set 2ip1 [+ $2i 1]
        lappend params "t$i [list [@ $pwlSeqVal $2i]]" "$type$i [list [@ $pwlSeqVal $2ip1]]"
    }
    foreach param $params {
        if {([llength [@ $param 1]]>1) && ([@ [@ $param 1] 1] eq "-eq")} {
            lappend paramList "[@ $param 0] [@ [@ $param 1] 0] -poseq"
        } else {
            lappend paramList "[@ $param 0] [@ $param 1] -pos"
        }
    }
    foreach paramName {rser cpar} {
        if {[dexist $arguments $paramName]} {
            set paramVal [dget $arguments $paramName]
            if {([llength $paramVal]>1) && ([@ $paramVal 1] eq "-eq")} {
                lappend paramList "$paramName [@ $paramVal 0] -eq"
            } else {
                lappend paramList "$paramName $paramVal"
            }
        }
    }
    set paramList [linsert $paramList 0 "model pwl -posnocheck"]
    next $type$name [list "np $npNode" "nm $nmNode"] $paramList
}

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-v0= -forbid {i0 voff ioff}}
        {-i0= -forbid {v0 voff ioff}}
        {-voff= -forbid {v0 i0 ioff}}
        {-ioff= -forbid {v0 i0 voff}}
        {-va= -forbid {ia vamp iamp}}
        {-ia= -forbid {va vamp iamp}}
        {-vamp= -forbid {va ia iamp}}
        {-iamp= -forbid {va ia vamp}}
        {-fc= -forbid fcar}
        {-fcar= -forbid fc}
        {-mdi= -required}
        {-fs= -forbid fsig}
        {-fsig= -forbid fs}
        -rser=
        -cpar=
    }]
    my AliasesKeysCheck $arguments [list v0 i0 voff ioff]
    my AliasesKeysCheck $arguments [list va ia vamp iamp]
    my AliasesKeysCheck $arguments [list fc fcar]
    my AliasesKeysCheck $arguments [list fs fsig]
    set paramsOrder [list v0 i0 voff ioff va ia vamp iamp fc fcar mdi fs fsig]
    lappend params "model sffm -posnocheck"
    my ParamsProcess $paramsOrder $arguments params
    dict for {paramName value} $arguments {
        if {$paramName ni $paramsOrder} {
            if {([llength $value]>1) && ([@ $value 1] eq "-eq")} {
                lappend params "$paramName [@ $value 0] -eq"
            } else {
                lappend params "$paramName $value"
            }
        }
    }
    next $type$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name type npNode nmNode args} {

    set arguments [argparse -inline {
        {-v0= -forbid {i0 voffset ioffset}}
        {-i0= -forbid {v0 voffset ioffset}}
        {-voffset= -forbid {v0 i0 ioffset}}
        {-ioffset= -forbid {v0 i0 voffset}}
        {-va= -forbid {ia vamp iamp}}
        {-ia= -forbid {va vamp iamp}}
        {-vamp= -forbid {va ia iamp}}
        {-iamp= -forbid {va ia vamp}}
        {-freq= -required}
        -td=
        {-theta= -require {td}}
        {-phase= -require {td theta} -forbid phi}
        {-phi= -require {td theta} -forbid phase}
        {-ncycles= -require {td theta}}
        -rser=
        -cpar=
    }]
    if {(![dexist $arguments phase] && ![dexist $arguments phi]) && [dexist $arguments ncycles]} {
        return -code error "-ncycles switch requires -phase or -phi switch"
    }
    my AliasesKeysCheck $arguments [list v0 i0 voffset ioffset]
    my AliasesKeysCheck $arguments [list va ia vamp iamp]
    set paramsOrder [list v0 i0 voffset ioffset va ia vamp iamp freq td theta phase phi ncycles]
    lappend params "model sin -posnocheck"
    my ParamsProcess $paramsOrder $arguments params
    dict for {paramName value} $arguments {
        if {$paramName ni $paramsOrder} {
            if {([llength $value]>1) && ([@ $value 1] eq "-eq")} {
                lappend params "$paramName [@ $value 0] -eq"
            } else {
                lappend params "$paramName $value"
            }
        }
    }
    next $type$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vac` that describes ac voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -dc - DC voltage value, default 0
    #  -ac - AC voltage value
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- <voltage> AC=<amplitude> [Rser=<value>] [Cpar=<value>]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::Sources::Vac new 1 netp netm -ac 10 -cpar 1e-9
    # ```
    # Synopsis: name npNode nmNode -ac value ?-dc value? ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vdc` that describes simple constant voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -dc - DC voltage value
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- <voltage> [Rser=<value>] [Cpar=<value>]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Vdc new 1 netp netm -dc 10 -rser 0.001
    # ```
    # Synopsis: name npNode nmNode -dc value ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vexp` that describes exponential voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -v1 - initial value
    #  -v2 - pulsed value
    #  -td1 - rise delay time
    #  -tau1 - rise time constant
    #  -td2 - fall delay time
    #  -tau2 - fall time constant
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- EXP(V1 V2 Td1 Tau1 Td2 Tau2)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Vexp new 1 net1 net2 -v1 0 -v2 1 -td1 1e-9 -tau1 1e-9 -td2 {td2 -eq} -tau2 10e-6
    # ```
    # Synopsis: name npNode nmNode -v1 value -v2 value -td1 value -tau1 value -td2 value -tau2 value
    #   ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vpulse` that describes pulse voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -low - low value, aliases: -voff, -ioff
    #  -high - high value, aliases: -von, ion
    #  -td - time delay
    #  -tr - rise time
    #  -tf - fall time
    #  -pw - width of pulse, alias -ton
    #  -per - period time, alias -tper
    #  -np - number of pulses, optional, alias -ncycles
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- PULSE(V1 V2 Tdelay Trise Tfall Ton Tperiod Ncycles)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Vpulse new 1 net1 net2 -low 0 -high 1 -td {td -eq} -tr 1e-9 -tf 1e-9 -pw 10e-6 -per 20e-6 -np {np -eq}
    # ```
    # Synopsis: name npNode nmNode -low|voff value -high|von value -td value -tr value -tf value -pw|ton value
    #   -per|tper value ?-np|ncycles value? ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vpwl` that describes piece-wise voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -seq - sequence of pwl points in form {t0 v0 t1 v1 t2 v2 t3 v3 ...}
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- PWL(t1 v1 t2 v2 t3 v3...)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Vpwl new 1 npNode nmNode -seq {0 0 {t1 -eq} 1 2 2 3 3 4 4}
    # ```
    # Synopsis: name npNode nmNode -seq list ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vsffm` that describes single-frequency FM voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -v0 - initial value, aliases: -voff, -i0, -ioff
    #  -va - pulsed value, aliases: -vamp, -ia, -iamp
    #  -fc - carrier frequency, alias -fcar
    #  -mdi - modulation index
    #  -fs - signal frequency, alias -fsig
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- SFFM(Voff Vamp Fcar MDI Fsig)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Ltspice::Sources::Vsin new 1 net1 net2 -v0 0 -va 1 -fc {freq -eq} -mdi 0 -fs 1e3
    # ```
    # Synopsis: name npNode nmNode -v0|voff value -va|vamp value -fc|fcar value -mdi value -fs|fsig value
    #   ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Vsin` that describes sinusoidal voltage source.
    #  name - name of the device without first-letter designator V
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -v0 - DC shift value, aliases: -voffset, -i0, -ioffset
    #  -va - amplitude value, aliases: -vamp, -ia, -iamp
    #  -freq - frequency of sinusoidal signal
    #  -td - time delay, optional
    #  -theta - damping factor, optional, require -td
    #  -phase - phase of signal, optional, require -td and -theta, alias -phi
    #  -ncycles - number of cycles, optional, require -td, -theta and -phase
    #  -rser - series resistor value, optional
    #  -cpar - parallel capacitor value, optional
    # ```
    # Vxxx n+ n- SINE(Voffset Vamp Freq Td Theta Phi Ncycles)
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Common::Sources::Vsin new 1 net1 net2 -v0 0 -va 2 -freq {freq -eq} -td 1e-6 -theta {theta -eq}
    # ```
    # Synopsis: name npNode nmNode -v0|voffset value -va|vamp value -freq value ?-td value ?-theta value
    #   ?-phase|phi value ?-ncycles value???? ?-rser value? ?-cpar value?
    next $name v $npNode $nmNode {*}$args
}