::SpiceGenTcl::Xyce::BasicDevicesTop, Main, Index

method constructor {name npNode nmNode args} {

    # Creates object of class `Capacitor` that describes capacitor.
    #  name - name of the device without first-letter designator C
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  args - keyword instance parameters
    # Capacitor type could be specified with additional switches: `-beh` if we
    # want to model circuit's variable dependent capacitor, or `-model modelName`
    # if we want to simulate capacitor with model card.
    # Simple capacitor:
    # ```
    # C<device name> <(+) node> <(-) node> <value> [device parameters]
    # ```
    # Example of class initialization as a simple capacitor:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Capacitor new 1 netp netm 1e-6 -tc1 1 -temp {temp -eq}
    # ```
    # Behavioral capacitor with C expression:
    # ```
    # C<device name> <(+) node> <(-) node> C={expression} [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Capacitor new 1 netp netm -c "V(a)+V(b)+pow(V(c),2)" -beh -tc1 1
    # ```
    # Behavioral capacitor with Q expression:
    # ```
    # C<device name> <(+) node> <(-) node> Q={expression} [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Capacitor new 1 netp netm -q "V(a)+V(b)+pow(V(c),2)" -beh -tc1 1
    # ```
    # Capacitor with model card:
    # ```
    # C<device name> <(+) node> <(-) node> <model name> [value] [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Capacitor new 1 netp netm -model capm -l 1e-6 -w 10e-6
    # ```
    set arguments [argparse -inline {
        {-c= -forbid {q}}
        {-q= -require {beh} -forbid {c model}}
        {-beh -forbid {model}}
        {-model= -forbid {beh}}
        -m=
        -temp=
        -tc1=
        -tc2=
        -ic=
        -age=
        -d=
        {-l= -require {model}}
        {-w= -require {model}}
    }]
    if {[dict exists $arguments model]} {
        lappend params "model [dict get $arguments model] -posnocheck"
    }
    if {[dict exists $arguments c]} {
        set cVal [dict get $arguments c]
        if {[dict exists $arguments beh]} {
            lappend params "c $cVal -eq"
        } elseif {([llength $cVal]>1) && ([lindex $cVal 1]=="-eq")} {
            lappend params "c [lindex $cVal 0] -poseq"
        } else {
            lappend params "c $cVal -pos"
        }
    } elseif {([dict exists $arguments model]==0) && ([dict exists $arguments q]==0)} {
        error "Capacitor value must be specified with '-c value'"
    }
    if {[dict exists $arguments q]} {
        set qVal [dict get $arguments q]
        if {[dict exists $arguments beh]} {
            lappend params "q $qVal -eq"
        } else {
            error "Charge of capacitor can't be specified without '-beh' switch"
        }
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {c q beh model}} {
            lappend params "$paramName $value"
        }
    }
    next c$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `GenSwitch` that describes generic switch device.
    #  name - name of the device without first-letter designator S
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  -model - model name
    #  -control - control equation
    #  -on/-off - initial state of switch
    # ```
    # S<name> <(+) switch node> <(-) switch node> <model name> [ON] [OFF] <control = expression>
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::GenSwitch new 1 net1 0 -model sw1 -control {I(VMON)}
    # ```
    set arguments [argparse -inline {
        {-model= -required}
        {-control= -required}
        {-on -forbid {off}}
        {-off -forbid {on}}
    }]
    lappend params "model [dict get $arguments model] -posnocheck"
    if {[dict exists $arguments on]} {
        lappend params {on -sw}
    } elseif {[dict exists $arguments off]} {
        lappend params {off -sw}
    }
    lappend params "control [dict get $arguments control] -eq"
    next s$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Inductor` that describes inductor.
    #  name - name of the device without first-letter designator L
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  args - keyword instance parameters
    # Inductor type could be specified with additional switch `-model modelName`
    # if we want to simulate inductor with model card.
    # Simple inductor:
    # ```
    # L<name> <(+) node> <(-) node> <value> [device parameters]
    # ```
    # Example of class initialization as a simple inductor:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Inductor new 1 netp netm -l 1e-6 -tc1 1 -temp {temp -eq}
    # ```
    # Behavioral inductor:
    # ```
    # L<name> <(+) node> <(-) node> [model] <value> [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Inductor new 1 netp netm -l "V(a)+V(b)+pow(V(c),2)" -beh -tc1 1
    # ```
    # Inductor with model card:
    # ```
    # L<name> <(+) node> <(-) node> [model] <value> [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Inductor new 1 netp netm -l 1e-6 -model indm
    # ```
    set arguments [argparse -inline {
        {-l= -required}
        -model=
        -m=
        -temp=
        -tc1=
        -tc2=
        -ic=
    }]
    if {[dict exists $arguments model]} {
        lappend params "model [dict get $arguments model] -posnocheck"
    }
    set lVal [dict get $arguments l]
    if {([llength $lVal]>1) && ([lindex $lVal 1]=="-eq")} {
        lappend params "l [lindex $lVal 0] -poseq"
    } else {
        lappend params "l $lVal -pos"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {l model}} {
            lappend params "$paramName $value"
        }
    }
    next l$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name npNode nmNode args} {

    # Creates object of class `Resistor` that describes resistor.
    #  name - name of the device without first-letter designator R
    #  npNode - name of node connected to positive pin
    #  nmNode - name of node connected to negative pin
    #  args - keyword instance parameters
    # Resistor type could be specified with additional switches: `-beh` if we
    # want to model circuit's variable dependent resistor, or `-model modelName`
    # if we want to simulate resistor with model card.
    # Simple resistor:
    # ```
    # R<name> <(+) node> <(-) node> <value> [device parameters]
    # ```
    # Example of class initialization as a simple resistor:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Resistor new 1 netp netm -r 1e3 -tc1 1 -temp {temp_amb -eq}
    # ```
    # Behavioral resistor:
    # ```
    # R<name> <(+) node> <(-) node> R ={expression} [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Resistor new 1 netp netm -r "V(a)+V(b)+pow(V(c),2)" -beh -tc1 1
    # ```
    # Resistor with model card:
    # ```
    # R<name> <(+) node> <(-) node> <model name> [value] [device parameters]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::Resistor new 1 netp netm -model resm -l 1e-6 -w 10e-6
    # ```
    set arguments [argparse -inline {
        -r=
        {-beh -forbid {model} -require {r}}
        {-model= -forbid {beh}}
        -m=
        -temp=
        -tc1=
        -tc2=
        -tce=
        {-l= -require {model}}
        {-w= -require {model}}
    }]
    if {[dict exists $arguments model]} {
        lappend params "model [dict get $arguments model] -posnocheck"
    }
    if {[dict exists $arguments r]} {
        set rVal [dict get $arguments r]
        if {[dict exists $arguments beh]} {
            lappend params "r $rVal -eq"
        } elseif {([llength $rVal]>1) && ([lindex $rVal 1]=="-eq")} {
            lappend params "r [lindex $rVal 0] -poseq"
        } else {
            lappend params "r $rVal -pos"
        }
    } elseif {[dict exists $arguments model]==0} {
        error "Resistor value must be specified with '-r value'"
    }
    dict for {paramName value} $arguments {
        if {$paramName ni {r beh model}} {
            lappend params "$paramName $value"
        }
    }
    next r$name [list "np $npNode" "nm $nmNode"] $params
}

method constructor {name pins subName params} {

    # Creates object of class `SubcircuitInstance` that describes subcircuit instance.
    #  name - name of the device without first-letter designator X
    #  pins - list of pins {{pinName nodeName} {pinName nodeName} ...}
    #  subName - name of subcircuit definition
    #  params - {{paramName paramValue ?-eq?} {paramName paramValue ?-eq?}}
    # ```
    # X<name> [nodes] <subcircuit name> [PARAMS: [<name> = <value>] ...]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::SubcircuitInstance new 1 {{plus net1} {minus net2}} rcnet {{r 1} {c cpar -eq}}
    # ```
    set params [linsert $params 0 "model $subName -posnocheck"]
    set params [linsert $params 1 "params PARAMS: -posnocheck"]
    next x$name $pins $params
}

method constructor {subcktObj name nodes args} {

    # Creates object of class `SubcircuitInstanceAuto` that describes subcircuit instance with already created subcircuit definition object.
    #  subcktObj - object of subcircuit that defines it's pins, subName and parameters
    #  nodes - list of nodes connected to pins in the same order as pins in subcircuit definition {nodeName1 nodeName2 ...}
    #  args - parameters as argument in form : -paramName {paramValue ?-eq?} -paramName {paramValue ?-eq?}
    # ```
    # X<name> [nodes] <subcircuit name> [PARAMS: [<name> = <value>] ...]
    # ```
    # Example of class initialization:
    # ```
    # ::SpiceGenTcl::Xyce::BasicDevices::SubcircuitInstanceAuto new $subcktObj 1 {net1 net2} -r 1 -c {cpar -eq}
    # ```

    # check that inputs object class is Subcircuit
    if {[info object class $subcktObj "::SpiceGenTcl::Subcircuit"]!=1} {
        set objClass [info object class $subcktObj]
        error "Wrong object class '$objClass' is passed as subcktObj, should be '::SpiceGenTcl::Subcircuit'"
    }
    # get name of subcircuit
    set subName [$subcktObj configure -Name]
    # get pins names of subcircuit
    set pinsNames [dict keys [$subcktObj getPins]]
    # check if number of pins in subcircuit definition matchs the number of supplied nodes
    if {[llength $pinsNames]!=[llength $nodes]} {
        error "Wrong number of nodes '[llength $nodes]' in definition, should be '[llength $pinsNames]'"
    }
    # create list of pins and connected nodes
    foreach pinName $pinsNames node $nodes {
        lappend pinsList "$pinName $node"
    }
    # get parameters names of subcircuit
    set paramsNames [dict keys [$subcktObj getParams]]
    foreach paramName $paramsNames {
        lappend paramDefList "-${paramName}="
    }
    if {[info exists paramDefList]} {
        # create definition for argparse module for passing parameters as optional arguments
        set arguments [argparse -inline "
            [join $paramDefList \n]
        "]
        # create list of parameters and values from which were supplied by args
        dict for {paramName value} $arguments {
            lappend params "$paramName $value"
        }
    } else {
        set params ""
    }
    set params [linsert $params 0 "model $subName -posnocheck"]
    set params [linsert $params 1 "params PARAMS: -posnocheck"]
    next x$name $pinsList $params
}